dotfiles.git

1) " Version 2023-11-13.1 - Prep to stop using vim-airline

2) set nocompatible    " Use Vim defaults, forget compatibility with vi.
3) set bs=2            " allow backspacing over everything in insert mode
4) set wildmenu        " Allows command-line completion with tab
5) set autoindent      " Copy indent from current line when starting a new line
6) set smartindent     " Do smart auto indenting when starting  new line
7) set smarttab        " Honor 'shiftwidth', 'tabstop' or 'softtabstop'
8) set hlsearch        " highlight all matches for previous search

9) set foldlevel=99

10) set nowrap          " no wrapping text lines on the screen (exceptions below)
11) set sidescroll=5

12) set listchars+=tab:>-,precedes:<,extends:>,nbsp:· " for :set list

13) 
14) if v:version >= 703
15)   " Do save the undo tree to file, but not in the local directory.
16)   " Don't forget to mkdir ~/.vim_undo
17)   set undodir=~/.vim_undo,.
18)   set undofile        " undo even after closing and reopening a file
19) endif
20) 
21) " The following two lines set the use of perl regex, aka "very magic"
22) nnoremap / /\v
23) vnoremap / /\v
24) 

25) " Make j and k move to the next row, not file line
26) nnoremap j gj
27) nnoremap k gk
28) 
29) " From Steve Losh: http://learnvimscriptthehardway.stevelosh.com/chapters/10.html

30) " Map jk to ESC in insert mode (except when navigating popup menu)
31) inoremap <expr> jk pumvisible() ? '' : '<esc>'
32) inoremap <expr> j pumvisible() ? '<Down>' : 'j'
33) inoremap <expr> k pumvisible() ? '<Up>' : 'k'

34) 

35) " https://stevelosh.com/blog/2010/09/coming-home-to-vim/#s3-why-i-came-back-to-vim
36) nnoremap <leader>v <C-w>v<C-w>l
37) nnoremap <C-h> <C-w>h
38) nnoremap <C-j> <C-w>j
39) nnoremap <C-k> <C-w>k
40) nnoremap <C-l> <C-w>l
41) 

42) " clear search highlights
43) nnoremap <cr> :noh<cr><cr>

44) 

45) " tab switches to previous/next buffer
46) nnoremap <Tab> :bp<cr>
47) nnoremap <S-Tab> :bn<cr>
48) 

49) syntax on
50) 
51) set t_Co=256
52) if v:version >= 703
53)   set colorcolumn=80
54) endif
55) if has('gui_running') " Didn't work: if &term != 'builtin_gui'
56)   " Light backgrounds for GUI experiences
57)   set background=light
58)   " colorscheme peaksea                        " install peaksea
59)   colorscheme tolerable                        " install tolerable
60)   if v:version >= 703
61)     highlight ColorColumn ctermbg=255 guibg=#F6F6F6
62)   endif

63)   highlight statusline   ctermfg=17 ctermbg=Gray " override scheme
64)   highlight statuslineNC ctermfg=20 ctermbg=LightGray" override scheme

65)   if has('win32')
66)     set guifont=DejaVu_Sans_Mono_for_Powerline:h10:cANSI:qDRAFT
67)   endif

68)   set lines=50 columns=100
69) else
70)   " Dark backgrounds for tty experiences
71)   set background=dark
72)   colorscheme desert                           " install desert
73)   if v:version >= 703

74)     highlight ColorColumn ctermbg=233 guibg=Black " dark gray (or 17, dark blue)

75)   endif

76)   highlight statusline   ctermfg=24 ctermbg=250  " override scheme
77)   highlight statuslineNC ctermfg=236 ctermbg=Gray  " override scheme

78)   highlight MatchParen   term=reverse ctermbg=23  " 23 is more subtle than default

79) endif

80) 

81) au InsertEnter * hi statusline guibg=Cyan ctermfg=25 guifg=Black ctermbg=248

82) au InsertLeave * hi statusline term=bold,reverse cterm=bold,reverse ctermfg=24 ctermbg=250 guifg=black guibg=#c2bfa5
83) 
84) let g:loaded_airline = 1  " For testing the statusline settings above

85) 
86) " set mouse=v     " visual mode, not working great for PuTTY
87) 
88) set tags=tags;/
89) 
90) set history=50

91) set laststatus=2
92) 
93) function! StatuslineGit()
94)   let l:branchname = system("git rev-parse --abbrev-ref HEAD 2>/dev/null | tr -d '\n'")
95)   return strlen(l:branchname) > 0 ? ' | branch:'.l:branchname : ''
96) endfunction
97) 
98) "    \ '' : 'S·BLOCK',
99) let g:currentmode={
100)     \ 'n'  : 'NORMAL',
101)     \ 'v'  : 'VISUAL',
102)     \ 'V'  : 'V·LINE',
103)     \ '' : 'V·BLOCK',
104)     \ 's'  : 'SELECT',
105)     \ 'S'  : 'S·LINE',
106)     \ 'i'  : 'INSERT',
107)     \ 'R'  : 'REPLACE',
108)     \ 'Rv' : 'V·REPLACE',
109)     \ 'c'  : 'COMMAND',
110)     \}
111) 
112) function! Trim_brackets(fn)

113)   if v:version > 800
114)     return trim(a:fn, "[]")
115)   else
116)     return a:fn
117)   endif

118) endfunction
119) 
120) set statusline=
121) set statusline+=\ %{g:currentmode[mode()]}
122) set statusline+=%{&paste?'\ \ ·\ PASTE':''}
123) "set statusline+=%{StatuslineGit()}
124) set statusline+=\ \|\ %f
125) set statusline+=%m\ 
126) set statusline+=%r\ 
127) set statusline+=%=
128) set statusline+=%h
129) set statusline+=\ %{Trim_brackets(&filetype)}\ 
130) set statusline+=%#StatusLineNC#
131) set statusline+=\ %{&fileencoding?&fileencoding:&encoding}
132) set statusline+=\[%{&fileformat}\]
133) set statusline+=\ \|\ %p%%\ Ξ
134) set statusline+=\ %l/%L\ :\ %c
135) set statusline+=\ 

136) 
137) set encoding=utf-8
138) 

139) " Fast saving
140) nmap <leader>w :w!<cr>

141) " I use relative number for cursor movement.
142) nmap <leader>r :set relativenumber!<cr>
143) nmap <leader>n :set number!<cr>
144) 
145) " Useful mappings for managing tabs

146) " Tab Previous: gT or C-PageUp
147) " Tab Next: gt or C-PageDown

148) nmap <leader>tn :tabnew
149) nmap <leader>to :tabonly<cr>
150) nmap <leader>tc :tabclose<cr>
151) nmap <leader>tm :tabmove

152) nmap <leader>1 1gt
153) nmap <leader>2 2gt
154) nmap <leader>3 3gt
155) nmap <leader>4 4gt
156) nmap <leader>5 5gt
157) nmap <leader>6 6gt
158) nmap <leader>7 7gt
159) nmap <leader>8 8gt
160) nmap <leader>9 9gt

161) 
162) " Open current buffer in new tab. Close with C-w,c
163) " https://vim.fandom.com/wiki/Maximize_window_and_return_to_previous_split_structure
164) function! OpenCurrentAsNewTab()

165)     let l:currentView = winsaveview()

166)     tabedit %

167)     call winrestview(l:currentView)

168) endfunction
169) nmap <leader>o :call OpenCurrentAsNewTab()<CR>

170) 

171) " git blame, show, diff and log

172) " Delete these functions when you install https://github.com/tpope/vim-fugitive

173) 
174) "A helper function that tries to show a buffer if it already exists
175) function! ShowBufInNewTab(bufname)
176)    let l:bnr = bufnr(a:bufname)
177)    if l:bnr > 0
178)        tabnew
179)        exec 'buffer ' . l:bnr
180)        return 1
181)    endif
182)    return 0
183) endfunction
184) 

185) function! GitBlame()

186)     let l:hash = expand('<cword>')

187)     let l:currentView = winsaveview()

188)     " If in a Blame window already, do blame for some prior commit

189)     if l:hash =~ '^[0-9a-f]\{7,40}$' && stridx(expand('%'), ' -- ') != -1

190)         let l:fname = split(expand('%'), ' -- ')[-1]

191)         let l:bufname = 'git blame ' . l:hash . '^ -- ' . l:fname
192)         if !ShowBufInNewTab(l:bufname)
193)             exec 'tabnew | r! git blame ' . l:hash . '^ -- ' . shellescape(l:fname)

194)             exec 'silent :file ' . fnameescape(l:bufname)

195)         endif

196)     else
197)         let l:fname = expand('%')

198)         let l:bufname = 'git blame -- ' . l:fname
199)         if !ShowBufInNewTab(l:bufname)
200)             exec 'tabnew | r! git blame -- ' . shellescape(l:fname)

201)             exec 'silent :file ' . fnameescape(l:bufname)

202)         endif

203)     endif
204)     0d_

205)     call winrestview(l:currentView)

206)     setl buftype=nofile
207) endfunction
208) command Blame :call GitBlame()
209) 

210) function! GitShow(commit_or_file)

211)     let l:fname = expand('%')

212)     let l:hash = expand('<cword>')

213)     if l:hash =~ '^[0-9a-f]\{7,40}$'
214)         if stridx(l:fname, ' -- ') != -1
215)             let l:fname = split(l:fname, ' -- ')[-1]

216)         endif

217)         if a:commit_or_file != "file"

218)             let l:bufname = 'git show ' . l:hash . ' -- ' . l:fname
219)             if !ShowBufInNewTab(l:bufname)
220)                 " Have Show show all the affected files, so don't actually use  "--"
221)                 " exec 'tabnew | r! git show ' . l:hash . ' -- ' . shellescape(l:fname)
222)                 exec 'tabnew | r! git show ' . l:hash
223)                 " We lie here (' -- ') to have a filename the other git commands can use.

224)                 exec 'silent :file ' . fnameescape(l:bufname)

225)             endif

226)         else

227)             let l:bufname = 'git show ' . l:hash . ':' . l:fname
228)             if !ShowBufInNewTab(l:bufname)
229)                 exec 'tabnew | r! git show ' . l:hash . ':' . shellescape(l:fname)

230)                 exec 'silent :file ' . fnameescape(l:bufname)

231)             endif

232)         endif

233)         setl buftype=nofile
234)         0d_
235)     else
236)         echo l:hash . ' is not a git hash.'
237)     endif

238) endfunction

239) command Show :call GitShow("commit")
240) command ShowFile :call GitShow("file")

241) 
242) function! GitDiff()

243)     let l:fname = expand('%:.')

244)     let l:buf = winbufnr(0)

245)     let l:commit = 'HEAD'

246)     let l:hash = expand('<cword>')

247) 

248)     " If the current word is a hash, then diff that vs. previous
249)     if l:hash =~ '^[0-9a-f]\{7,40}$' && stridx(expand('%'), ' -- ') != -1
250)         let l:fname = split(expand('%'), ' -- ')[-1]
251)         exec ':tabnew | silent r! git show ' . l:hash . '^:$(git rev-parse --show-prefix)' . shellescape(l:fname)
252)         setl buftype=nofile
253)         0d_

254)         exec 'silent :file ' . fnameescape('git show '.l:hash .'^:'.l:fname)

255) 

256)         exec 'vne | silent r! git show ' . l:hash . ':$(git rev-parse --show-prefix)' . shellescape(l:fname)
257)         setl buftype=nofile

258)         exec 'silent :file ' . fnameescape('git show '.l:hash.':'.l:fname)

259)         0d_
260)     else
261)         " If the buffer is not different then repo, then diff HEAD vs file's previous commit
262)         let l:o = system("git status --porcelain | grep " . l:fname)
263)         if v:shell_error != 0
264)             let l:commit = system('git log -2 --pretty=format:"%h" -- ' . l:fname . ' | tail -n 1')
265)         endif

266) 

267)         " Bug if l:filename includes ".."
268)         exec ':tabnew | r! git show ' . l:commit . ':$(git rev-parse --show-prefix)' . l:fname
269)         setl buftype=nofile
270)         0d_

271)         exec 'silent :file ' . fnameescape('git show '.l:commit.':'.l:fname)

272)         exec 'vert sb '.l:buf
273)     endif

274)     windo diffthis
275)     setl buftype=nofile
276)     wincmd r
277)     wincmd l
278) endfunction
279) command Diff :call GitDiff()

280) 

281) function! GitLog(flags)

282)     let l:fname = expand('%')

283)     if stridx(l:fname, ' -- ') != -1
284)         let l:fname = split(l:fname, ' -- ')[-1]
285)     endif

286)     let l:bufname = 'git log ' . a:flags . '-- ' . l:fname

287)     if !ShowBufInNewTab(l:bufname)

288)         exec 'tabnew | r! git log --no-color --graph --date=short ' . a:flags . '--pretty="format:\%h \%ad \%s \%an \%d" -- ' . shellescape(l:fname)

289)         setl buftype=nofile
290)         0d_

291)         exec 'silent :file ' . fnameescape(l:bufname)

292)     endif

293) endfunction

294) command Logall :call GitLog('--all ')
295) command Log :call GitLog('')

296) 

297) " pastetoggle
298) nmap <leader>p :set invpaste paste?<cr>
299) 

300) " Control+p to paste onto next line
301) nmap <C-p> :pu<cr>
302) 

303) " Make netrw's Explore behave a little like NERDTreeToggle
304) " http://vimcasts.org/blog/2013/01/oil-and-vinegar-split-windows-and-project-drawer/

305) function! ToggleNetrw()

306)   if bufwinnr("NetrwTreeListing") > 0
307)     for i in range(1, bufnr("$"))
308)       if (getbufvar(i, "&filetype") == "netrw")

309)         silent exe "bwipeout " . i

310)         return
311)       endif
312)     endfor
313)   endif

314)   silent Vexplore %:p:h

315) endfunction
316) nmap <leader>e :call ToggleNetrw()<cr>
317) 

318) " install taglist
319) let Tlist_GainFocus_On_ToggleOpen = 1  " Jump to taglist window on open
320) let Tlist_Exit_OnlyWindow = 1          " if you are the last, kill yourself
321) let Tlist_Close_On_Select = 1          " Close taglist window on select
322) nmap <leader>l :TlistToggle<cr>
323) 
324) " install vim-bbye
325) nmap <leader>bd :Bdelete<cr>

326) 
327) " Visual mode mappings
328) """
329) 
330) " map sort function to a key
331) vnoremap <leader>s :sort<cr>
332) 
333) "easier moving of code blocks

334) vnoremap < <gv
335) vnoremap > >gv

336) 
337) " If too many file system events are getting triggered.
338) set nobackup       " ~ files
339) set nowritebackup  " Don't write buff to temp, delete orig, rename temp to orig
340) set noswapfile     " .swp files
341) 
342) " Allow tags to open another buffer even if this one is modified
343) set hidden
344) 
345) " Switch between source and header files
346) function! SwitchSourceHeader()
347)   let s:ext  = expand("%:e")
348)   let s:base = expand("%:t:r")
349)   let s:cmd  = "find " . s:base
350)   if (s:ext == "cpp" || s:ext == "c")
351)     if findfile(s:base . ".h"  ) != "" | exe s:cmd . ".h"   | return | en
352)     if findfile(s:base . ".hpp") != "" | exe s:cmd . ".hpp" | return | en
353)   else
354)     if findfile(s:base . ".cpp") != "" | exe s:cmd . ".cpp" | return | en
355)     if findfile(s:base . ".c"  ) != "" | exe s:cmd . ".c"   | return | en
356)   endif
357) endfunc
358) 
359) " Demonstrates a way to look in a mirror directory
360) " function! OpenOther()
361) "    if expand("%:e") == "cpp"
362) "      exe "split" fnameescape(expand("%:p:r:s?src?include?").".h")
363) "    elseif expand("%:e") == "h"
364) "      exe "split" fnameescape(expand("%:p:r:s?include?src?").".cpp")
365) "    endif
366) " endfunc
367) 
368) " Delete trailing white space on save, useful for Python and CoffeeScript ;)
369) function! DeleteTrailingWS()
370)   exe "normal mz"
371)   %s/\s\+$//ge
372)   exe "normal `z"
373) endfunc
374) 

375) function! OpenInOtherWindow()
376)   if winnr('$') == 1
377)     exe "wincmd F"
378)   else
379)     let curNum = winnr()
380)     let oldBuf = bufnr( "%" )
381)     if curNum == 1
382)       let othNum = 2
383)     else
384)       let othNum = 1
385)     endif
386)     exe "normal! gF"
387)     let newBuf = bufnr( "%" )
388)     let newLine = line(".")
389)     exe 'hide buf' oldBuf
390)     exe othNum . "wincmd w"
391)     exe 'hide buf' newBuf
392)     exe "normal! " . newLine . "G"
393)   endif
394) endfunc
395) 
396) nmap <silent> <leader>F :call OpenInOtherWindow()<cr>

397) nmap <silent> <leader>f :call OpenInOtherWindow()<cr>

398) 

399) if has("autocmd")
400)   autocmd BufWrite *.py :call DeleteTrailingWS()  " Delete trailing whitespace
401)   " Don't let smartindent unindent the # character in Python files
402)   autocmd FileType python  inoremap # X<c-h>#

403)   autocmd FileType python,c,cpp,php,brs,sh  set expandtab  " Use spaces instead of tabs

404)   autocmd Filetype make    setl noexpandtab       " ...not for files that use tabs.
405) 
406)   " Use the vim command %retab before applying the following
407)   " two with files that have 8-space tabs.

408)   autocmd FileType c,cpp,python,php  set tabstop=4

409)   autocmd FileType c,cpp,php  set shiftwidth=4

410) 
411)   autocmd FileType python  set foldmethod=indent  " 'za' to fold
412) 

413)   autocmd FileType c,cpp nmap <buffer> <leader>s :call SwitchSourceHeader()<cr>

414)   autocmd FileType c,cpp set foldmethod=syntax
415) 

416)   " autocmd FileType rokulog :let g:airline_extensions = []
417)   " autocmd FileType rokulog :let g:airline_section_warning = airline#section#create([])
418)   autocmd FileType rokulog :let g:airline#extensions#whitespace#enabled = 0

419) 

420)   if v:version >= 703
421)     " I toggle out of relative number when Vim's focus is lost, because
422)     " if I'm not editing, then I may be referring to errors with line numbers.
423)     autocmd FocusLost * if &relativenumber | set number | endif
424)     autocmd FocusGained * if &number | set relativenumber | endif
425)   endif
426) 

427)   autocmd BufRead *.txt set wrap linebreak   " "soft" wrap of existing lines
428)   autocmd BufRead README set wrap linebreak  " "soft" wrap of existing lines

429)   autocmd BufRead *.rs :setlocal tags=./rusty-tags.vi;/

430) 
431)   " When editing a file, always jump to the last cursor position
432)   autocmd BufReadPost *

433)   \ if &ft != "p4changelist" && &ft != "gitcommit" && line("'\"") > 0 && line ("'\"") <= line("$") |

434)   \   exe "normal! g'\"" |
435)   \ endif
436) endif
437) 
438) " This requires vim to be compiled with +python
439) " Use auto complete in insert mode with ctrl-x, ctrl-o
440) " See :help new-omni-completion for more.
441) filetype plugin on
442) set omnifunc=syntaxcomplete#Complete

443) 
444) " Torn on whether I like the omni completion preview window left open or not.
445) " autocmd CompleteDone * pclose
446) 
447) " Omni completion via ctrl-space (in addition to ctrl-x ctrl-o)
448) inoremap <Nul> <C-x><C-o>
449) 

450) " cscope
451) if has("cscope")
452)     set cscopetag  " Use both cscope and ctag for 'ctrl-]'

453)     set csto=1     " 0=cscope first; 1=ctags first

454)     set cscopequickfix=s-,c-,d-,i-,t-,e-,a- " cscope to quickfix window
455) 

456)     set nocsverb
457)     " add any database in current directory
458)     if filereadable("cscope.out")
459)         cs add cscope.out
460)     " else add database pointed to by environment
461)     elseif $CSCOPE_DB != ""
462)         cs add $CSCOPE_DB
463)     endif
464)     set csverb

465) endif
466) 

467) " From https://stackoverflow.com/questions/15393301/how-to-automatically-sort-quickfix-entries-by-line-text-in-vim
468) " :grep term %
469) " :grep -r term path/
470) " :cw
471) " :ccl (or C-w,q)

472) autocmd! QuickfixCmdPost * call MaybeSortQuickfix('QfStrCmp')
473) 
474) function! MaybeSortQuickfix(fn)
475) "    exe 'normal! '  " Doesn't work. Wanted to jump back to where we were.
476)     let t = getqflist({'title': 1}).title

477)     " Only sort the files if for search-style commands, not "make".

478)     if stridx(t, "cs ") == 0 || stridx(t, ":gr") == 0 || stridx(t, ":vim") == 0 || stridx(t, ":rg") == 0

479)         call setqflist(sort(getqflist(), a:fn), 'r')
480)         call setqflist([], 'r', {'title': t})
481)     endif
482)     cwindow

483) endfunction
484) 
485) function! QfStrCmp(e1, e2)
486)     let [t1, t2] = [bufname(a:e1.bufnr), bufname(a:e2.bufnr)]
487)     return t1 <# t2 ? -1 : t1 ==# t2 ? 0 : 1
488) endfunction
489) 

490) " Use ripgrep for search instead of grep
491) if executable('rg')
492)     " set grepprg=rg\ --vimgrep\ --hidden\ —glob '!.git'
493)     set grepprg=rg
494) endif
495) " Navigate quickfix list with ease
496) nnoremap <silent> [q :cprevious<CR>
497) nnoremap <silent> ]q :cnext<CR>
498) 

499) " I use Roboto Mono from https://github.com/powerline/fonts

500) " On iTerm2, Preferences -> Profiles -> Text -> Font

501) " Cygwin64 won't let you choose it. Launch Cygwin64 as follows:
502) " C:\cygwin64\bin\mintty.exe -i /Cygwin-Terminal.ico -o Font="Roboto Mono for Powerline" -

503) 

504) " Settings that make netrw more like NERDTree
505) let g:netrw_banner = 0
506) let g:netrw_liststyle = 3

507) let g:netrw_browse_split = 4

508) let g:netrw_altv = 1

509) " set g:netrw_winsize to negative for absolute width, positive for relative
510) let g:netrw_winsize = -36
511) " let g:netrw_winsize = 35

512) " sort is affecting only: directories on the top, files below
513) let g:netrw_sort_sequence = '[\/]$,*'

514) 
515) " When using vim-airline
516) let g:airline_powerline_fonts = 1

517) if !exists('g:airline_symbols')
518)     let g:airline_symbols = {}
519) endif
520) let g:airline_symbols.whitespace = '✖'
521) let g:airline_symbols.linenr = 'Ξ'

522) let g:airline_symbols.maxlinenr = ''

523) " If using a powerline font, don't override .readonly. Otherwise pick one.
524) "let g:airline_symbols.readonly = '◆'
525) "let g:airline_symbols.readonly = '🔒'

526) 
527) " If no "...for Powerline" font is available, uncomment these four:

528) let g:airline_left_sep = '▌'
529) let g:airline_right_sep = '▐'
530) let g:airline_left_alt_sep = '|'
531) let g:airline_right_alt_sep = '|'

532) 

533) let g:airline_theme = 'powerlineish'

534) let g:airline#extensions#wordcount#enabled = 0

535) " let g:airline_exclude_filetypes = []

536) 
537) " Experimenting with vim-rooter
538) let g:rooter_patterns = ['.git', 'Makefile', 'builds/']

539) let g:rooter_cd_cmd = 'lcd'
540) let g:rooter_manual_only = 1