dotfiles.git

1) " Version 2024-03-17.1 - status line color tweak

2) set nocompatible    " Use Vim defaults, forget compatibility with vi.
3) set bs=2            " allow backspacing over everything in insert mode
4) set wildmenu        " Allows command-line completion with tab
5) set autoindent      " Copy indent from current line when starting a new line
6) set smartindent     " Do smart auto indenting when starting  new line
7) set smarttab        " Honor 'shiftwidth', 'tabstop' or 'softtabstop'
8) set hlsearch        " highlight all matches for previous search

9) set foldlevel=99

10) set nowrap          " no wrapping text lines on the screen (exceptions below)
11) set sidescroll=5

12) set listchars+=tab:>-,precedes:<,extends:>,nbsp:· " for :set list

13) set iskeyword+=-    " Add - to list of non-word-breaking chars.

14) set incsearch       " Navigate to matched strings while typing. Toggle: :set is!

15) set scrolloff=0     " EC2 defaults to 5. Set explicitly to be consistent

16) set formatoptions+=j " Delete comment character when joining commented lines.

17) set ttimeoutlen=100 " Affects Esc key, not leader.

18) set noruler         " Don't show cursor pos on right side of status bar

19) " Set the title of the terminal window. Consider changing titlestring, %t, %M
20) set title titlestring=%f%m\ -\ vim

21) 
22) if v:version >= 703
23)   " Do save the undo tree to file, but not in the local directory.
24)   " Don't forget to mkdir ~/.vim_undo
25)   set undodir=~/.vim_undo,.
26)   set undofile        " undo even after closing and reopening a file
27) endif
28) 

29) " Make j and k move to the next row, not file line
30) nnoremap j gj
31) nnoremap k gk
32) 
33) " From Steve Losh: http://learnvimscriptthehardway.stevelosh.com/chapters/10.html

34) " Map jk to ESC in insert mode (except when navigating popup menu)
35) inoremap <expr> jk pumvisible() ? '' : '<esc>'
36) inoremap <expr> j pumvisible() ? '<Down>' : 'j'
37) inoremap <expr> k pumvisible() ? '<Up>' : 'k'

38) inoremap <expr> <Tab> pumvisible() ? '<Down>' : '<Tab>'
39) inoremap <expr> <S-Tab> pumvisible() ? '<Up>' : '<S-Tab>'
40) inoremap <expr> <cr> pumvisible() ? '<C-y>' : '<cr>'

41) 

42) " https://stevelosh.com/blog/2010/09/coming-home-to-vim/#s3-why-i-came-back-to-vim
43) nnoremap <leader>v <C-w>v<C-w>l
44) nnoremap <C-h> <C-w>h
45) nnoremap <C-j> <C-w>j
46) nnoremap <C-k> <C-w>k
47) nnoremap <C-l> <C-w>l
48) 

49) " clear search highlights
50) nnoremap <cr> :noh<cr><cr>

51) 

52) " tmux 3.2+ doesn't send C-i, so have Alacritty iTerm2 map C-i to <leader>i
53) " iTerm2: Settings > Keys > Key Bindings > + > Shortcut:^i Action:Send Text "\i"
54) nnoremap <leader>i <C-i>
55) " Use (Shift-)Tab to navigate buffers, retain C-i/C-o for jumps.

56) " Test with this:

57) " nvim -Nu NONE +'nno <C-i> :echom "C-i pressed"<cr>' +'nno <tab> :echom "Tab pressed"<cr>'
58) "if stridx(expand($TERM), 'xterm') == 0
59)   nnoremap <C-i> <C-i>
60)   nmap <Tab> :bn<cr>
61) "endif

62) nnoremap <S-Tab> :bp<cr>

63) 

64) " Use yy to yank a whole line, use Y to yank to end of line like C and D
65) nnoremap Y y$
66) 

67) syntax on
68) 
69) set t_Co=256
70) if v:version >= 703
71)   set colorcolumn=80
72) endif
73) if has('gui_running') " Didn't work: if &term != 'builtin_gui'
74)   " Light backgrounds for GUI experiences
75)   set background=light
76)   " colorscheme peaksea                        " install peaksea
77)   colorscheme tolerable                        " install tolerable
78)   if v:version >= 703
79)     highlight ColorColumn ctermbg=255 guibg=#F6F6F6
80)   endif

81)   highlight statusline   ctermfg=17 ctermbg=Gray  " override scheme
82)   highlight statuslineNC ctermfg=20 ctermbg=LightGray  " override scheme

83)   if has('win32')
84)     set guifont=DejaVu_Sans_Mono_for_Powerline:h10:cANSI:qDRAFT
85)   endif

86)   set lines=50 columns=100
87) else
88)   " Dark backgrounds for tty experiences
89)   set background=dark
90)   colorscheme desert                           " install desert
91)   if v:version >= 703

92)     highlight ColorColumn ctermbg=233 guibg=Black " dark gray (or 17, dark blue)

93)   endif

94)   highlight statusline   ctermfg=23 ctermbg=250  " override scheme

95) "  highlight User1        ctermfg=250 ctermbg=30

96)   highlight statuslineNC ctermfg=237 ctermbg=Gray  " override scheme

97)   highlight MatchParen   term=reverse ctermbg=23  " 23 is more subtle than default

98) endif

99) 

100) au InsertEnter * hi statusline guibg=Cyan ctermfg=25 guifg=Black ctermbg=248

101) au InsertLeave * hi statusline term=bold,reverse cterm=bold,reverse ctermfg=23 ctermbg=250 guifg=black guibg=#c2bfa5

102) 

103) " set mouse=v     " visual mode, not working great for PuTTY
104) 
105) set tags=tags;/
106) 

107) set history=500

108) set laststatus=2
109) 

110) function! GitBranch()

111)   let l:branchname = system("git -C " . expand('%:p:h') . " rev-parse --abbrev-ref HEAD 2>/dev/null | tr -d '\n'")

112)   return strlen(l:branchname) > 0 ? '  │  '.l:branchname : ''

113) endfunction
114) 

115) function! EncodingAndFormat()
116)   if (len(&fileencoding) && &fileencoding != 'utf-8') || &fileformat != 'unix'
117)     return &fileencoding?&fileencoding:&encoding .'['. &fileformat . '] │ '
118)   endif
119)   return ''
120) endfunction
121) 

122) function! OnRuler()
123)   if &ruler
124)     return '│ '.line('.').':'.col('.').' '
125)   endif
126)   return ''
127) endfunction
128) 

129) function! Current_mode()
130)   let l:currentmode={

131)     \ 'n'  : 'NORMAL',
132)     \ 'v'  : 'VISUAL',
133)     \ 'V'  : 'V·LINE',
134)     \ '' : 'V·BLOCK',
135)     \ 's'  : 'SELECT',
136)     \ 'S'  : 'S·LINE',
137)     \ 'i'  : 'INSERT',

138)     \ 'r'  : 'I·REPLACE',

139)     \ 'R'  : 'REPLACE',
140)     \ 'Rv' : 'V·REPLACE',
141)     \ 'c'  : 'COMMAND',
142)     \}

143)     return get(l:currentmode, mode(), mode())
144) endfunction

145) 
146) function! Trim_brackets(fn)

147)   if v:version > 800
148)     return trim(a:fn, "[]")
149)   else
150)     return a:fn
151)   endif

152) endfunction
153) 

154) set statusline=\ %{Current_mode()}

155) set statusline+=%{&paste?'\ \ ·\ PASTE':''}

156) set statusline+=%{b:git_branch}

157) set statusline+=\ │\ %f

158) set statusline+=%m
159) set statusline+=\ %r
160) set statusline+=\ %=

161) set statusline+=%h

162) set statusline+=\ %{Trim_brackets(&filetype)}
163) set statusline+=\ %#StatusLineNC#

164) set statusline+=\ %{b:enc_fmt}
165) set statusline+=%p%%\ of

166) set statusline+=\ %L\ 

167) set statusline+=%{OnRuler()}

168) 
169) set encoding=utf-8
170) 

171) " Fast saving
172) nmap <leader>w :w!<cr>

173) " I use relative number for cursor movement.
174) nmap <leader>r :set relativenumber!<cr>
175) nmap <leader>n :set number!<cr>
176) 
177) " Useful mappings for managing tabs

178) " Tab Previous: gT or C-PageUp
179) " Tab Next: gt or C-PageDown

180) nmap <leader>tn :tabnew
181) nmap <leader>to :tabonly<cr>
182) nmap <leader>tc :tabclose<cr>
183) nmap <leader>tm :tabmove

184) nmap <leader>1 1gt
185) nmap <leader>2 2gt
186) nmap <leader>3 3gt
187) nmap <leader>4 4gt
188) nmap <leader>5 5gt
189) nmap <leader>6 6gt
190) nmap <leader>7 7gt
191) nmap <leader>8 8gt
192) nmap <leader>9 9gt

193) 
194) " Open current buffer in new tab. Close with C-w,c
195) " https://vim.fandom.com/wiki/Maximize_window_and_return_to_previous_split_structure
196) function! OpenCurrentAsNewTab()

197)     let l:currentView = winsaveview()

198)     tabedit %

199)     call winrestview(l:currentView)

200) endfunction
201) nmap <leader>o :call OpenCurrentAsNewTab()<CR>

202) 
203) " pastetoggle
204) nmap <leader>p :set invpaste paste?<cr>
205) 

206) " Control+p to paste onto next line
207) nmap <C-p> :pu<cr>
208) 

209) " Make netrw's Explore behave a little like NERDTreeToggle
210) " http://vimcasts.org/blog/2013/01/oil-and-vinegar-split-windows-and-project-drawer/

211) function! ToggleNetrw()

212)   if bufwinnr("NetrwTreeListing") > 0
213)     for i in range(1, bufnr("$"))
214)       if (getbufvar(i, "&filetype") == "netrw")

215)         silent exe "bwipeout " . i

216)         return
217)       endif
218)     endfor
219)   endif

220)   silent Vexplore %:p:h

221) endfunction
222) nmap <leader>e :call ToggleNetrw()<cr>
223) 

224) " install taglist
225) let Tlist_GainFocus_On_ToggleOpen = 1  " Jump to taglist window on open
226) let Tlist_Exit_OnlyWindow = 1          " if you are the last, kill yourself
227) let Tlist_Close_On_Select = 1          " Close taglist window on select

228) let Tlist_Inc_Winwidth = 0             " Only needed for neovim in tmux

229) nmap <leader>l :TlistToggle<cr>
230) 
231) " install vim-bbye
232) nmap <leader>bd :Bdelete<cr>

233) 
234) " Visual mode mappings
235) """
236) 
237) " map sort function to a key
238) vnoremap <leader>s :sort<cr>
239) 
240) "easier moving of code blocks

241) vnoremap < <gv
242) vnoremap > >gv

243) 
244) " If too many file system events are getting triggered.
245) set nobackup       " ~ files
246) set nowritebackup  " Don't write buff to temp, delete orig, rename temp to orig
247) set noswapfile     " .swp files
248) 
249) " Allow tags to open another buffer even if this one is modified
250) set hidden
251) 
252) " Switch between source and header files
253) function! SwitchSourceHeader()
254)   let s:ext  = expand("%:e")
255)   let s:base = expand("%:t:r")
256)   let s:cmd  = "find " . s:base
257)   if (s:ext == "cpp" || s:ext == "c")
258)     if findfile(s:base . ".h"  ) != "" | exe s:cmd . ".h"   | return | en
259)     if findfile(s:base . ".hpp") != "" | exe s:cmd . ".hpp" | return | en
260)   else
261)     if findfile(s:base . ".cpp") != "" | exe s:cmd . ".cpp" | return | en
262)     if findfile(s:base . ".c"  ) != "" | exe s:cmd . ".c"   | return | en
263)   endif
264) endfunc
265) 
266) " Demonstrates a way to look in a mirror directory
267) " function! OpenOther()
268) "    if expand("%:e") == "cpp"
269) "      exe "split" fnameescape(expand("%:p:r:s?src?include?").".h")
270) "    elseif expand("%:e") == "h"
271) "      exe "split" fnameescape(expand("%:p:r:s?include?src?").".cpp")
272) "    endif
273) " endfunc
274) 
275) " Delete trailing white space on save, useful for Python and CoffeeScript ;)
276) function! DeleteTrailingWS()
277)   exe "normal mz"
278)   %s/\s\+$//ge
279)   exe "normal `z"
280) endfunc
281) 

282) function! OpenInOtherWindow()
283)   if winnr('$') == 1
284)     exe "wincmd F"
285)   else
286)     let curNum = winnr()
287)     let oldBuf = bufnr( "%" )
288)     if curNum == 1
289)       let othNum = 2
290)     else
291)       let othNum = 1
292)     endif
293)     exe "normal! gF"
294)     let newBuf = bufnr( "%" )
295)     let newLine = line(".")
296)     exe 'hide buf' oldBuf
297)     exe othNum . "wincmd w"
298)     exe 'hide buf' newBuf
299)     exe "normal! " . newLine . "G"
300)   endif
301) endfunc
302) 
303) nmap <silent> <leader>F :call OpenInOtherWindow()<cr>

304) nmap <silent> <leader>f :call OpenInOtherWindow()<cr>

305) 

306) if has("autocmd")
307)   autocmd BufWrite *.py :call DeleteTrailingWS()  " Delete trailing whitespace
308)   " Don't let smartindent unindent the # character in Python files
309)   autocmd FileType python  inoremap # X<c-h>#

310)   autocmd FileType python,c,cpp,php,brs,sh  set expandtab  " Use spaces instead of tabs

311)   autocmd Filetype make    setl noexpandtab       " ...not for files that use tabs.
312) 
313)   " Use the vim command %retab before applying the following
314)   " two with files that have 8-space tabs.

315)   autocmd FileType c,cpp,python,php  set tabstop=4

316)   autocmd FileType c,cpp,php  set shiftwidth=4

317) 
318)   autocmd FileType python  set foldmethod=indent  " 'za' to fold
319) 

320)   autocmd FileType c,cpp nmap <buffer> <leader>s :call SwitchSourceHeader()<cr>

321)   autocmd FileType c,cpp set foldmethod=syntax
322) 

323) " https://jeffkreeftmeijer.com/vim-number/
324) augroup numbertoggle
325)   autocmd!
326)   autocmd BufEnter,FocusGained,InsertLeave,WinEnter * if &nu && mode() != "i" | set rnu   | endif
327)   autocmd BufLeave,FocusLost,InsertEnter,WinLeave   * if &nu                  | set nornu | endif
328) augroup END

329) 

330)   autocmd BufRead *.txt set wrap linebreak   " "soft" wrap of existing lines
331)   autocmd BufRead README set wrap linebreak  " "soft" wrap of existing lines

332)   autocmd BufRead *.rs :setlocal tags=./rusty-tags.vi;/

333) 

334)   " When editing a file, always jump to the last cursor position...

335)   autocmd BufReadPost *

336)   \ if &ft != "gitcommit" && line("'\"") > 0 && line ("'\"") <= line("$") |

337)   \   exe "normal! g`\"" |

338)   \ endif

339)   " ...except for gitcommit where we always want to start at the top (nvim)

340)   autocmd FileType gitcommit exe "normal! gg"

341) 

342)   autocmd BufNewFile,BufReadPost *
343)   \ let b:git_branch = GitBranch() |
344)   \ let b:enc_fmt = EncodingAndFormat()
345)   autocmd BufEnter *
346)   \ let b:git_branch = GitBranch() |
347)   \ let b:enc_fmt = EncodingAndFormat()

348) endif
349) 
350) " This requires vim to be compiled with +python
351) " Use auto complete in insert mode with ctrl-x, ctrl-o
352) " See :help new-omni-completion for more.
353) filetype plugin on
354) set omnifunc=syntaxcomplete#Complete

355) 
356) " Torn on whether I like the omni completion preview window left open or not.
357) " autocmd CompleteDone * pclose
358) 
359) " Omni completion via ctrl-space (in addition to ctrl-x ctrl-o)
360) inoremap <Nul> <C-x><C-o>
361) 

362) " These two commands display syntax/highlight info for what's under the cursor.
363) if exists(":SynStack") != 2
364)     command SynStack :echo map(synstack(line('.'), col('.')), 'synIDattr(v:val, "name")')
365) endif
366) 
367) function! SynGroup()
368)     let l:s = synID(line('.'), col('.'), 1)
369)     echo synIDattr(l:s, 'name') . ' -> ' . synIDattr(synIDtrans(l:s), 'name')
370) endfun
371) command Hi :call SynGroup()
372) 

373) " cscope
374) if has("cscope")
375)     set cscopetag  " Use both cscope and ctag for 'ctrl-]'

376)     set csto=1     " 0=cscope first; 1=ctags first

377)     set cscopequickfix=s-,c-,d-,i-,t-,e-,a- " cscope to quickfix window
378) 

379)     set nocsverb
380)     " add any database in current directory
381)     if filereadable("cscope.out")
382)         cs add cscope.out
383)     " else add database pointed to by environment
384)     elseif $CSCOPE_DB != ""
385)         cs add $CSCOPE_DB
386)     endif
387)     set csverb

388) endif
389) 

390) " From https://stackoverflow.com/questions/15393301/how-to-automatically-sort-quickfix-entries-by-line-text-in-vim
391) " :grep term %
392) " :grep -r term path/
393) " :cw
394) " :ccl (or C-w,q)

395) autocmd! QuickfixCmdPost * call MaybeSortQuickfix('QfStrCmp')
396) 
397) function! MaybeSortQuickfix(fn)
398) "    exe 'normal! '  " Doesn't work. Wanted to jump back to where we were.
399)     let t = getqflist({'title': 1}).title

400)     " Only sort the files if for search-style commands, not "make".

401)     if stridx(t, "cs ") == 0 || stridx(t, ":gr") == 0 || stridx(t, ":vim") == 0 || stridx(t, ":rg") == 0

402)         call setqflist(sort(getqflist(), a:fn), 'r')
403)         call setqflist([], 'r', {'title': t})
404)     endif
405)     cwindow

406) endfunction
407) 
408) function! QfStrCmp(e1, e2)
409)     let [t1, t2] = [bufname(a:e1.bufnr), bufname(a:e2.bufnr)]
410)     return t1 <# t2 ? -1 : t1 ==# t2 ? 0 : 1
411) endfunction
412) 

413) " Use ripgrep for search instead of grep
414) if executable('rg')
415)     " set grepprg=rg\ --vimgrep\ --hidden\ —glob '!.git'
416)     set grepprg=rg
417) endif
418) " Navigate quickfix list with ease
419) nnoremap <silent> [q :cprevious<CR>
420) nnoremap <silent> ]q :cnext<CR>
421) 

422) " From `:help :DiffOrig`.

423) if exists(":DiffOrig") != 2
424)   command DiffOrig vert new | set bt=nofile | r ++edit # | 0d_

425)     \ | diffthis | wincmd p | diffthis

426) endif

427) 

428) " I use Roboto Mono from https://github.com/powerline/fonts

429) " On iTerm2, Preferences -> Profiles -> Text -> Font

430) " Cygwin64 won't let you choose it. Launch Cygwin64 as follows:
431) " C:\cygwin64\bin\mintty.exe -i /Cygwin-Terminal.ico -o Font="Roboto Mono for Powerline" -

432) 

433) " Settings that make netrw more like NERDTree
434) let g:netrw_banner = 0
435) let g:netrw_liststyle = 3

436) let g:netrw_browse_split = 4

437) let g:netrw_altv = 1

438) " set g:netrw_winsize to negative for absolute width, positive for relative
439) let g:netrw_winsize = -36
440) " let g:netrw_winsize = 35

441) " sort is affecting only: directories on the top, files below
442) let g:netrw_sort_sequence = '[\/]$,*'

443) 

444) " Experimenting with vim-rooter
445) let g:rooter_patterns = ['.git', 'Makefile', 'builds/']

446) let g:rooter_cd_cmd = 'lcd'
447) let g:rooter_manual_only = 1