components/mytask.brs (0a6f57c) - dxb_channel.git

mytask.brs

sub init()
    m.top.functionName = "executeTask"
end sub

function getDeviceInfo(deviceInfo as object) as Object
    ' Try to get various info from an ECP call
    aa = {}
    request = CreateObject("roUrlTransfer")
    request.SetUrl("http://localhost:8060/query/device-info")
    root = CreateObject("roXMLElement")
    if root.Parse(request.GetToString()) then
        elements = root.GetNamedElements("serial-number")
        if elements.Count() > 0
            aa["serial number"] = elements[0].GetText()
        end if
        elements = root.GetNamedElements("device-id")
        if elements.Count() > 0
            aa["device ID"] = elements[0].GetText()
        end if
        elements = root.GetNamedElements("model-number")
        if elements.Count() > 0
            aa.["model"] = elements[0].GetText()
        end if
        elements = root.GetNamedElements("build-number")
        if elements.Count() > 0
            fv =  elements[0].GetText()
            elements = root.GetNamedElements("software-version")
            if elements.Count() > 0
                aa.["firmware version"] = fv + " (" + elements[0].GetText() + " " + mid(fv, 9, 4) + ")"
            else
                aa.["firmware version"] = fv
            end if
        end if
        return aa
    end if
    ' That did not work, so make a custom one.
    clientID = Right(deviceInfo.GetChannelClientId(), 6)
    modelID = deviceInfo.GetModel()
    return { "client ID": clientID, "model": modelID }
end function

function executeTask() as void

am = CreateObject("roAppManager")
    aaRunParams = am.GetRunParams()
    for each key in aaRunParams
        val = aaRunParams[key]
        m.top.updateText = key + " = " + val.ToStr()
    end for
    ' m.top.updateText = "devID " + CreateObject("roAppInfo").GetDevID()

deviceInfo = CreateObject("roDeviceInfo")
    infoaa = getDeviceInfo(deviceInfo)
    if infoaa <> invalid:
        for each key in infoaa
            val = infoaa[key]
            m.top.updateText = key + " = " + val.ToStr()
        end for
    else
        m.top.updateText = "(Could not get device info.)"
    end if
    port = CreateObject("roMessagePort")
    deviceInfo.SetMessagePort(port)
    input = CreateObject("roInput")
    input.SetMessagePort(port)

success = deviceInfo.EnableLinkStatusEvent(true)
    if not success m.top.updateTextLower = "EnableLinkStatusEvent failure"
    success = deviceInfo.EnableAudioDestinationEvent(true)
    if not success then m.top.updateTextLower = "EnableAudioDestinationEvent failure"
    success = deviceInfo.EnableAudioGuideChangedEvent(true)
    if not success then m.top.updateTextLower = "EnableAudioGuideChangedEvent failure"
    success = deviceInfo.EnableAppFocusEvent(true)
    if not success then m.top.updateTextLower = "EnableAppFocusEvent failure"
    success = deviceInfo.EnableCodecCapChangedEvent(true)
    if not success then m.top.updateTextLower = "EnableCodecCapChangedEvent failure"

while(true)
        msg = wait(0, port)
        msgType = type(msg)

dt = Mid(CreateObject("roDateTime").ToISOString(), 15, 5)

if msgType = "roHdmiStatusEvent"
            aa = msg.GetInfo()
            v = aa.LookupCI("Plugged")
            if v <> invalid then m.top.updateTextLower = dt + " HDMI plugged " + v.toStr()
        elseif msgType = "roCECStatusEvent"
            aa = msg.GetInfo()
            v = aa.LookupCI("Active")
            if v <> invalid then m.top.updateTextLower = dt + " CEC Status " + v.toStr()
        elseif msgType = "roDeviceInfoEvent"
            aa = msg.GetInfo()
            v = aa.LookupCI("Mute")
            if v <> invalid then  m.top.updateTextLower = dt + " Mute " + v.toStr()
            v = aa.LookupCI("Mode")
            if v <> invalid then m.top.updateTextLower = dt + " Mode " + v.toStr()
            v = aa.LookupCI("linkStatus")
            if v <> invalid then m.top.updateTextLower = dt + " LinkStatus " + v.toStr()
            v = aa.LookupCI("audioGuideEnabled")
            if v <> invalid then m.top.updateTextLower = dt + " AudioGuide " + v.toStr()
            v = aa.LookupCI("appFocused")
            if v <> invalid then m.top.updateTextLower = dt + " appFocused " + v.toStr()
            v = aa.LookupCI("audioCodecCapabilityChanged")
            if v <> invalid then m.top.updateTextLower = dt + " audioCodecCapabilityChanged " + v.toStr()
        elseif msgType = "roInputEvent"
            info = msg.GetInfo()
            m.top.updateTextLower = dt + " Input " + FormatJSON(info)
        else
            m.top.updateTextLower = dt + " msgType " + msgType
        end if
    end while

end function

dxb_channel.git

Fix static analysis problems. Add some logging.