dotfiles.git

1) " Version 2024-03-07.1 - First misc fixes

2) set bs=2            " allow backspacing over everything in insert mode
3) set smartindent     " Do smart auto indenting when starting  new line
4) set foldlevel=99
5) set nowrap          " no wrapping text lines on the screen (exceptions below)
6) set sidescroll=5

7) set listchars+=tab:>-,precedes:<,extends:>,nbsp:·,eol:\\u21b5 " for :set list

8) set scrolloff=0     " EC2 defaults to 5. Set explicitly to be consistent
9) set notermguicolors " Only needed for neovim while I port my color schemes

10) set undofile        " undo even after closing and reopening a file

11) set noshowcmd       " Show size of selected area in visual mode on last line

12) set ruler           " Show coordinates on status line

13) set hidden          " Don't abandon Scratch buffer when hidden.

14) "set cursorline     " For CursorLineNR formatting similar to pre 8.0.

15) set culopt=number   " Otherwise diff views have an underline. neovim issue 9800

16) " Set the title of the terminal window. Consider changing titlestring, %t, %M
17) set title titlestring=%f%m\ -\ nvim

18) 
19) " WSL clipboard-tool fom 'help clipboard'
20) "let g:clipboard = {
21) "            \   'name': 'WslClipboard',
22) "            \   'copy': {
23) "            \      '+': '/mnt/c/Windows/system32/clip.exe',
24) "            \      '*': '/mnt/c/Windows/system32/clip.exe',
25) "            \    },
26) "            \   'paste': {
27) "            \      '+': 'powershell.exe -c [Console]::Out.Write($(Get-Clipboard -Raw).tostring().replace("`r", ""))',
28) "            \      '*': 'powershell.exe -c [Console]::Out.Write($(Get-Clipboard -Raw).tostring().replace("`r", ""))',
29) "            \   },
30) "            \   'cache_enabled': 0,
31) "            \ }
32) 
33) " Yank and put into the system Clipboard (register + or *)
34) " Otherwise make explicit commands "+yy "+y "+Y (or * instead of + as needed)
35) " N.B. Don't use unnamed register for clipboard (set clipboard=unnamed)
36) "      Delete operations would overwrite clipboard before pasting.

37) " Also N.B. cscope_maps might assign <leader>c to its prefix.

38) nnoremap <leader>c "+
39) vnoremap <leader>c "+

40) 
41) " Make j and k move to the next row, not file line
42) nnoremap j gj
43) nnoremap k gk
44) 
45) " From Steve Losh: http://learnvimscriptthehardway.stevelosh.com/chapters/10.html
46) " Map jk to ESC in insert mode (except when navigating popup menu)
47) inoremap <expr> jk pumvisible() ? '' : '<esc>'
48) inoremap <expr> j pumvisible() ? '<Down>' : 'j'
49) inoremap <expr> k pumvisible() ? '<Up>' : 'k'

50) inoremap <expr> <Tab> pumvisible() ? '<Down>' : '<Tab>'
51) inoremap <expr> <S-Tab> pumvisible() ? '<Up>' : '<S-Tab>'
52) inoremap <expr> <cr> pumvisible() ? '<C-y>' : '<cr>'

53) 
54) " https://stevelosh.com/blog/2010/09/coming-home-to-vim/#s3-why-i-came-back-to-vim
55) nnoremap <leader>v <C-w>v<C-w>l
56) nnoremap <C-h> <C-w>h
57) nnoremap <C-j> <C-w>j
58) nnoremap <C-k> <C-w>k
59) nnoremap <C-l> <C-w>l
60) 
61) " clear search highlights
62) nnoremap <cr> :noh<cr><cr>
63) 

64) " tmux 3.2+ doesn't send C-i, so have Alacritty iTerm2 map C-i to <leader>i
65) " iTerm2: Settings > Keys > Key Bindings > + > Shortcut:^i Action:Send Text "\i"

66) nnoremap <leader>i <C-i>

67) " Use (Shift-)Tab to navigate buffers, retain C-i/C-o for jumps.

68) " Test with this:
69) " nvim -Nu NONE +'nno <C-i> :echom "C-i pressed"<cr>' +'nno <tab> :echom "Tab pressed"<cr>'

70) "if stridx(expand($TERM), 'xterm') == 0

71)   nnoremap <C-i> <C-i>

72)   nmap <Tab> :bn<cr>

73) "endif

74) nnoremap <S-Tab> :bp<cr>

75) 
76) set t_Co=256

77) set colorcolumn=80

78) if has('gui_running') " Didn't work: if &term != 'builtin_gui'
79)   " Light backgrounds for GUI experiences
80)   set background=light
81)   " colorscheme peaksea
82)   colorscheme tolerable

83)   highlight ColorColumn ctermbg=255 guibg=#F6F6F6

84)   highlight statusline   ctermfg=17 ctermbg=Gray  " override scheme
85)   highlight statuslineNC ctermfg=20 ctermbg=LightGray  " override scheme

86)   if has('win32')
87)     set guifont=DejaVu_Sans_Mono_for_Powerline:h10:cANSI:qDRAFT
88)   endif
89)   set lines=50 columns=100
90) else
91)   " Dark backgrounds for tty experiences
92)   set background=dark
93)   colorscheme nvim_desert
94) endif
95) 

96) au InsertEnter * hi statusline guibg=Cyan ctermfg=25 guifg=Black ctermbg=248

97) au InsertLeave * hi statusline term=bold,reverse cterm=bold,reverse ctermfg=23 ctermbg=250 guifg=black guibg=#c2bfa5

98) 

99) " See https://neovim.io/doc/user/vim_diff.html#_default-mouse

100) " set mouse=  " neovim defaults to nvi

101) 

102) " Don't move the cursor when activating window (incompatible on PuTTY)
103) augroup NO_CURSOR_MOVE_ON_FOCUS
104)   au!
105)   au FocusLost * let g:oldmouse=&mouse | set mouse=
106)   au FocusGained * if exists('g:oldmouse') | let &mouse=g:oldmouse | unlet g:oldmouse | endif
107) augroup END
108) 

109) " Set jump point from before mouse click.
110) nnoremap <LeftMouse> m'<LeftMouse>
111) 

112) " Make c-] show a list of tags, or jump straight if only single tag

113) " Note cscope_maps plugin might map c-].

114) nnoremap <c-]> g<c-]>
115) vnoremap <c-]> g<c-]>
116) nnoremap g<c-]> <c-]>
117) vnoremap g<c-]> <c-]>

118) " Consider neovim default "./tags;,tags"

119) set tags=tags;/
120) 

121) set history=500

122) 

123) function! GitBranch()

124)   let l:branchname = system("git -C " . expand('%:p:h') . " rev-parse --abbrev-ref HEAD 2>/dev/null | tr -d '\n'")

125)   return strlen(l:branchname) > 0 ? '  │  '.l:branchname : ''

126) endfunction
127) 

128) function! EncodingAndFormat()
129)   if (len(&fileencoding) && &fileencoding != 'utf-8') || &fileformat != 'unix'
130)     return &fileencoding?&fileencoding:&encoding .'['. &fileformat . '] │ '
131)   endif
132)   return ''
133) endfunction
134) 

135) function! OnRuler()
136)   if &ruler
137)     return '│ '.line('.').':'.col('.').' '
138)   endif
139)   return ''
140) endfunction
141) 

142) function! Current_mode()
143)   let l:currentmode={
144)     \ 'n'  : 'NORMAL',
145)     \ 'v'  : 'VISUAL',
146)     \ 'V'  : 'V·LINE',
147)     \ '' : 'V·BLOCK',
148)     \ 's'  : 'SELECT',
149)     \ 'S'  : 'S·LINE',
150)     \ 'i'  : 'INSERT',
151)     \ 'r'  : 'I·REPLACE',
152)     \ 'R'  : 'REPLACE',
153)     \ 'Rv' : 'V·REPLACE',
154)     \ 'c'  : 'COMMAND',
155)     \}
156)     return get(l:currentmode, mode(), mode())
157) endfunction
158) 
159) function! Trim_brackets(fn)
160)   if v:version > 800
161)     return trim(a:fn, "[]")
162)   else
163)     return a:fn
164)   endif
165) endfunction
166) 
167) set statusline=\ %{Current_mode()}
168) set statusline+=%{&paste?'\ \ ·\ PASTE':''}

169) set statusline+=%{b:git_branch}

170) set statusline+=\ │\ %f
171) set statusline+=%m
172) set statusline+=\ %r
173) set statusline+=\ %=
174) set statusline+=%h
175) set statusline+=\ %{Trim_brackets(&filetype)}
176) set statusline+=\ %#StatusLineNC#

177) set statusline+=\ %{b:enc_fmt}
178) set statusline+=%p%%\ of

179) set statusline+=\ %L\ 

180) set statusline+=%{OnRuler()}

181) 
182) " Fast saving
183) nmap <leader>w :w!<cr>
184) " I use relative number for cursor movement.
185) nmap <leader>r :set relativenumber!<cr>
186) nmap <leader>n :set number!<cr>
187) 
188) " Useful mappings for managing tabs
189) " Tab Previous: gT or C-PageUp
190) " Tab Next: gt or C-PageDown
191) nmap <leader>tn :tabnew
192) nmap <leader>to :tabonly<cr>
193) nmap <leader>tc :tabclose<cr>
194) nmap <leader>tm :tabmove
195) nmap <leader>1 1gt
196) nmap <leader>2 2gt
197) nmap <leader>3 3gt
198) nmap <leader>4 4gt
199) nmap <leader>5 5gt
200) nmap <leader>6 6gt
201) nmap <leader>7 7gt
202) nmap <leader>8 8gt
203) nmap <leader>9 9gt
204) 
205) " Open current buffer in new tab. Close with C-w,c
206) " https://vim.fandom.com/wiki/Maximize_window_and_return_to_previous_split_structure
207) function! OpenCurrentAsNewTab()
208)     let l:currentView = winsaveview()
209)     tabedit %
210)     call winrestview(l:currentView)
211) endfunction
212) nmap <leader>o :call OpenCurrentAsNewTab()<CR>
213) 
214) " pastetoggle
215) nmap <leader>p :set invpaste paste?<cr>
216) 
217) " Control+p to paste onto next line
218) nmap <C-p> :pu<cr>
219) 
220) " Make netrw's Explore behave a little like NERDTreeToggle
221) " http://vimcasts.org/blog/2013/01/oil-and-vinegar-split-windows-and-project-drawer/
222) function! ToggleNetrw()
223)   if bufwinnr("NetrwTreeListing") > 0
224)     for i in range(1, bufnr("$"))
225)       if (getbufvar(i, "&filetype") == "netrw")
226)         silent exe "bwipeout " . i
227)         return
228)       endif
229)     endfor
230)   endif
231)   silent Vexplore %:p:h
232) endfunction
233) nmap <leader>e :call ToggleNetrw()<cr>
234) 
235) " install taglist
236) let Tlist_GainFocus_On_ToggleOpen = 1  " Jump to taglist window on open
237) let Tlist_Exit_OnlyWindow = 1          " if you are the last, kill yourself
238) let Tlist_Close_On_Select = 1          " Close taglist window on select

239) let Tlist_Inc_Winwidth = 0             " Only needed for neovim in tmux

240) nmap <leader>l :TlistToggle<cr>
241) 
242) " install vim-bbye
243) nmap <leader>bd :Bdelete<cr>
244) 
245) " Visual mode mappings
246) """
247) 
248) " map sort function to a key
249) vnoremap <leader>s :sort<cr>
250) 
251) "easier moving of code blocks
252) vnoremap < <gv
253) vnoremap > >gv
254) 
255) " If too many file system events are getting triggered.
256) set nobackup       " ~ files
257) set nowritebackup  " Don't write buff to temp, delete orig, rename temp to orig
258) set noswapfile     " .swp files
259) 
260) " Switch between source and header files
261) function! SwitchSourceHeader()
262)   let s:ext  = expand("%:e")
263)   let s:base = expand("%:t:r")
264)   let s:cmd  = "find " . s:base
265)   if (s:ext == "cpp" || s:ext == "c")
266)     if findfile(s:base . ".h"  ) != "" | exe s:cmd . ".h"   | return | en
267)     if findfile(s:base . ".hpp") != "" | exe s:cmd . ".hpp" | return | en
268)   else
269)     if findfile(s:base . ".cpp") != "" | exe s:cmd . ".cpp" | return | en
270)     if findfile(s:base . ".c"  ) != "" | exe s:cmd . ".c"   | return | en
271)   endif
272) endfunc
273) 
274) " Demonstrates a way to look in a mirror directory
275) " function! OpenOther()
276) "    if expand("%:e") == "cpp"
277) "      exe "split" fnameescape(expand("%:p:r:s?src?include?").".h")
278) "    elseif expand("%:e") == "h"
279) "      exe "split" fnameescape(expand("%:p:r:s?include?src?").".cpp")
280) "    endif
281) " endfunc
282) 
283) " Delete trailing white space on save, useful for Python and CoffeeScript ;)
284) function! DeleteTrailingWS()
285)   exe "normal mz"
286)   %s/\s\+$//ge
287)   exe "normal `z"
288) endfunc
289) 
290) function! OpenInOtherWindow()
291)   if winnr('$') == 1
292)     exe "wincmd F"
293)   else
294)     let curNum = winnr()
295)     let oldBuf = bufnr( "%" )
296)     if curNum == 1
297)       let othNum = 2
298)     else
299)       let othNum = 1
300)     endif
301)     exe "normal! gF"
302)     let newBuf = bufnr( "%" )
303)     let newLine = line(".")
304)     exe 'hide buf' oldBuf
305)     exe othNum . "wincmd w"
306)     exe 'hide buf' newBuf
307)     exe "normal! " . newLine . "G"
308)   endif
309) endfunc
310) 
311) nmap <silent> <leader>F :call OpenInOtherWindow()<cr>
312) nmap <silent> <leader>f :call OpenInOtherWindow()<cr>
313) 
314) if has("autocmd")
315)   autocmd BufWrite *.py :call DeleteTrailingWS()  " Delete trailing whitespace
316)   " Don't let smartindent unindent the # character in Python files
317)   autocmd FileType python  inoremap # X<c-h>#
318)   autocmd FileType python,c,cpp,php,brs,sh  set expandtab  " Use spaces instead of tabs

319)   autocmd FileType make    setl noexpandtab                " ...not for files that use tabs.
320)   autocmd FileType markdown  set iskeyword+=-  " Add - to list of non-word-breaking chars.

321) 
322)   " Use the vim command %retab before applying the following
323)   " two with files that have 8-space tabs.
324)   autocmd FileType c,cpp,python,php  set tabstop=4
325)   autocmd FileType c,cpp,php  set shiftwidth=4
326) 
327)   autocmd FileType python  set foldmethod=indent  " 'za' to fold
328) 
329)   autocmd FileType c,cpp nmap <buffer> <leader>s :call SwitchSourceHeader()<cr>
330)   autocmd FileType c,cpp set foldmethod=syntax
331) 

332) " https://jeffkreeftmeijer.com/vim-number/

333) " Disabling for now, just keep the mode that was explicitly requested.
334) "augroup numbertoggle
335) "  autocmd!
336) "  autocmd BufEnter,FocusGained,InsertLeave,WinEnter * if &nu && mode() != "i" | set rnu   | endif
337) "  autocmd BufLeave,FocusLost,InsertEnter,WinLeave   * if &nu                  | set nornu | endif
338) "augroup END

339) 
340)   autocmd BufRead *.txt set wrap linebreak   " "soft" wrap of existing lines
341)   autocmd BufRead README set wrap linebreak  " "soft" wrap of existing lines
342)   autocmd BufRead *.rs :setlocal tags=./rusty-tags.vi;/
343) 

344)   " When editing a file, always jump to the last cursor position...

345)   autocmd BufReadPost *

346)   \ if line("'\"") > 0 && line ("'\"") <= line("$") |

347)   \   exe "normal! g`\"" |

348)   \ endif

349)   " ...except for gitcommit where we always want to start at the top
350)   autocmd FileType gitcommit exe "normal! gg"

351) 

352)   autocmd BufNewFile,BufReadPost *
353)   \ let b:git_branch = GitBranch() |
354)   \ let b:enc_fmt = EncodingAndFormat()
355)   autocmd BufEnter *
356)   \ let b:git_branch = GitBranch() |
357)   \ let b:enc_fmt = EncodingAndFormat()

358) 
359)   " I only use a cursorline style for the number column
360)   autocmd OptionSet number,relativenumber if v:option_new | set cursorline | endif

361) endif
362) 
363) " This requires vim to be compiled with +python
364) " Use auto complete in insert mode with ctrl-x, ctrl-o
365) " See :help new-omni-completion for more.
366) filetype plugin on
367) set omnifunc=syntaxcomplete#Complete
368) 
369) " Torn on whether I like the omni completion preview window left open or not.
370) " autocmd CompleteDone * pclose
371) 
372) " Omni completion via ctrl-space (in addition to ctrl-x ctrl-o)

373) inoremap <C-Space> <C-x><C-o>

374) 

375) " These two commands display syntax/highlight info for what's under the cursor.
376) if exists(":SynStack") != 2
377)     command SynStack :echo map(synstack(line('.'), col('.')), 'synIDattr(v:val, "name")')
378) endif
379) 
380) function! SynGroup()
381)     let l:s = synID(line('.'), col('.'), 1)
382)     echo synIDattr(l:s, 'name') . ' -> ' . synIDattr(synIDtrans(l:s), 'name')
383) endfun
384) command Hi :call SynGroup()

385) 
386) " From https://stackoverflow.com/questions/15393301/how-to-automatically-sort-quickfix-entries-by-line-text-in-vim
387) " :grep term %
388) " :grep -r term path/
389) " :cw
390) " :ccl (or C-w,q)
391) autocmd! QuickfixCmdPost * call MaybeSortQuickfix('QfStrCmp')
392) 
393) function! MaybeSortQuickfix(fn)
394) "    exe 'normal! '  " Doesn't work. Wanted to jump back to where we were.
395)     let t = getqflist({'title': 1}).title
396)     " Only sort the files if for search-style commands, not "make".
397)     if stridx(t, "cs ") == 0 || stridx(t, ":gr") == 0 || stridx(t, ":vim") == 0 || stridx(t, ":rg") == 0
398)         call setqflist(sort(getqflist(), a:fn), 'r')
399)         call setqflist([], 'r', {'title': t})
400)     endif
401)     cwindow
402) endfunction
403) 
404) function! QfStrCmp(e1, e2)
405)     let [t1, t2] = [bufname(a:e1.bufnr), bufname(a:e2.bufnr)]
406)     return t1 <# t2 ? -1 : t1 ==# t2 ? 0 : 1
407) endfunction
408) 
409) " Use ripgrep for search instead of grep
410) if executable('rg')
411)     " set grepprg=rg\ --vimgrep\ --hidden\ —glob '!.git'
412)     set grepprg=rg
413) endif
414) " Navigate quickfix list with ease
415) nnoremap <silent> [q :cprevious<CR>
416) nnoremap <silent> ]q :cnext<CR>
417) 

418) " From `:help :DiffOrig`.

419) if exists(":DiffOrig") != 2
420)   command DiffOrig vert new | set bt=nofile | r ++edit # | 0d_

421)     \ | diffthis | wincmd p | diffthis

422) endif

423) 

424) " I use Roboto Mono from https://github.com/powerline/fonts
425) " On iTerm2, Preferences -> Profiles -> Text -> Font
426) " Cygwin64 won't let you choose it. Launch Cygwin64 as follows:
427) " C:\cygwin64\bin\mintty.exe -i /Cygwin-Terminal.ico -o Font="Roboto Mono for Powerline" -
428) 
429) " Settings that make netrw more like NERDTree
430) let g:netrw_banner = 0
431) let g:netrw_liststyle = 3
432) let g:netrw_browse_split = 4
433) let g:netrw_altv = 1
434) " set g:netrw_winsize to negative for absolute width, positive for relative
435) let g:netrw_winsize = -36
436) " let g:netrw_winsize = 35
437) " sort is affecting only: directories on the top, files below
438) let g:netrw_sort_sequence = '[\/]$,*'
439) 
440) " Experimenting with vim-rooter
441) let g:rooter_patterns = ['.git', 'Makefile', 'builds/']
442) let g:rooter_cd_cmd = 'lcd'
443) let g:rooter_manual_only = 1
444) 

445) " 'Rainbow Parentheses Improved' https://github.com/luochen1990/rainbow/

446) let g:rainbow_conf = {
447) \   'ctermfgs': ['223', 'lightblue', '180', 'green', 'yellow', '111'],
448) \   'separately': { 'rokulog': 0 }
449) \ }

450) let g:rainbow_active = 1 "set to 0 if you want to enable it later via :RainbowToggle
451) 

452) " See https://wiki.dlma.com/neovim#cscope
453) lua << EOF

454)   require('cscope_maps').setup({ 
455)     disable_maps = true, -- Mapping C-] to :Cstag <cword> worse than :tag <cword>

456)   -- Alternatively, if we liked the mappings, then customise these two:
457)   --    skip_input_prompt = true,
458)   --    cscope = { skip_picker_for_single_result = true },

459)   })

460) 
461)   -- From https://www.reddit.com/r/neovim/comments/wcq6sp/override_file_type_detection_for_existing/
462)   vim.filetype.add {

463)     pattern = {
464)       ['.*'] = {
465)         priority = -math.huge,
466)         function(path, bufnr)
467)           local rokulog_pat = [[^\d\{2\}-\d\{2\} \d\{2\}:\d\{2\}:\d\{2\}.\d\{3\}\s\+\(!\|n\|dev\|\d\+\(_[0-9a-f]\+\)\?\|tvinput\.\S\+\)\?[ *]\[]]
468)           if vim.fn.has('nvim-0.10') == 1 then
469)             local content = vim.api.nvim_buf_get_lines(bufnr, 0, 1, false)[1] or ''
470)             if vim.regex(rokulog_pat):match_str(content) ~= nil then
471)               return 'rokulog'
472)             end
473)           else
474)             local content = vim.filetype.getlines(bufnr, 1)
475)             if vim.filetype.matchregex(content, rokulog_pat) then
476)               return 'rokulog'
477)             end
478)           end
479)         end,
480)       },

481)     },

482)   }